The bivariate normal (Mathematica calls it the Binormal Distribution)

μ1 = 0;
μ2 = 0.5;
ρ=0.5;
σ1 = 1;
σ2 = 0.6;
{Plot3D[PDF[BinormalDistribution[{μ1,μ2},{σ1,σ2},ρ],{x,y}],{x,-3,3},{y,-3,3},PlotRange->All,MeshFunctions->{#3&},MeshShading->{None,Red,None,Yellow},PlotPoints->50,ImageSize->400],

ContourPlot[PDF[BinormalDistribution[{μ1,μ2},{σ1,σ2},ρ],{x,y}],{x,-3,3},{y,-3,3},PlotRange->All,PlotPoints->50,ImageSize->400]}

The Cauchy Distribution

data=RandomVariate[CauchyDistribution[0,1], 10^4];

Show[Histogram[data,{-18,20,0.5},PDF],Plot[PDF[TruncatedDistribution[{-18,20},CauchyDistribution[0,1]],x],{x,-18,20},PlotStyle->Thick,PlotRange->All]]

Mean[CauchyDistribution[0,1]]

Variance[CauchyDistribution[0,1]]

Table[Cumulant[CauchyDistribution[0,1],n],{n,1,10}]

WHY THE MEAN IS UNDETERMINED, EVEN THOUGH THE FUNCTION IS SYMMETRIC

First I will gradually determine the mean of a Gaussian

dataG = RandomVariate[NormalDistribution[0,1],(10^4)];
accumulatedMeanG=Accumulate[dataG]/Range[1,(10^4)];
ListLinePlot[accumulatedMeanG,PlotRange->All]

Clearly the means converges to zero

Now I will do the same thing for Cauchy

dataC = RandomVariate[CauchyDistribution[0,1],(10^4)];
accumulatedMeanC=Accumulate[dataC]/Range[1,(10^4)];
ListLinePlot[accumulatedMeanC]

We see the presence of extreme events: that is, big jumps that mess everything up. 
This is what is really different about long-tail distributions.